rebol [
	Title: "COMLib overview diagram"
	File: %COMLib-overview-diagram.r
	Date: 30-Jun-2006
	Version: 1.0.2
	Progress: 0.95
	Status: "working"
	Needs: [View]
	Author: "Anton Rolls"
	Language: "English"
	Purpose: {Show the parts used by COMLib involved in the interfacing between REBOL and COM}
	Usage: {}
	History: [
		1.0.0 [12-Dec-2005 {First version} "Anton"]
		1.0.1 [26-Jun-2006 {wrapped in USE to avoid setting global words, no longer saves to disk, just returns image} "Anton"]
		1.0.2 [30-Jun-2006 {added "Win32" text} "Anton"]
	]
	ToDo: {
	- 
	}
	Notes: {"the yellow boxes are the parts that we supply in the COMLib distribution"}
]

;query/clear system/words

use [window r-box d-box c-box img][

	window: center-face layout [
		backcolor pewter
		origin 60x60

		style tbox box edge [size: 2x2 color: black] font [color: black shadow: none] top 
		style connector box 60x9 effect compose/deep [
			;merge luma 20 
			draw [pen black  fill-pen black  circle 4x4 3 circle (51x0 + 4x4) 3  line-width 2 line 4x4 (51x0 + 4x4)]
		]

		space 0

		r-box: tbox 140x140 (red * 0.8) "REBOL"
		at (r-box/offset + 26x30)
		tbox 108x60 (yellow * 0.8) "COMLib.r"
		tbox 108x30 tan "your-script.r" font [style: none]

		at (r-box/offset + 160x30)
		d-box: tbox 160x60 (yellow * 0.8) "com2rebol.dll"
		at (d-box/offset + 26x24)
		tbox 128x30 (yellow * 0.7) "disphelper"

		at (d-box/offset + 180x10)
		c-box: tbox 70x48 silver "COM"

		at (c-box/offset + 100x-40)
		tbox 140x140 silver "eg. Office apps:^/Word^/Excel^/IE^/Outlook^/etc."

		; connecting lines *------*

		at (r-box/offset + 117x64) connector
		
		at (d-box/offset + 138x34) connector
		
		at (c-box/offset + (c-box/size * 1x0) - 0x20)
		box 30x100 effect [
			;merge luma 20
			draw [pen black  fill-pen black  line-width 1.5  arrow 1x1  line 2x35 28x20  line 2x45 28x45  line 2x55 28x70]
		]
	]
	window/edge: make window/edge [size: 2x2 color: coal]
	window/text: "Win32"
	window/font: r-box/font

	img: to-image window
	;view center-face layout [image img]
	;save/png %COMLib-overview-diagram.png img

	img ; <-- return the image
]

;probe query/clear system/words